Oracle de XMLDB #8 - またまた少々脱線 Tweet

久々にOracle11gのXML DBネタなのだが、XQueryなどのXMLマスタープロフェッショナル（データベース）絡みのネタからはまた脱線。SQL/XMLネタを一つ。

以前、Oracle10g R1/R2上でRSS FEEDをPL/SQLで取得してOracle Application Expressで表示なんてことをやっていた。
（３３回も連載してたっけ。。。。）
Mac De PL/SQL RSS Reader #1
Mac De PL/SQL RSS Reader #2

それらのエントリで、参照するXML文書の文字エンコーディングとデータベースキャラクタセットが異なると文字化けを起こしてしまうHttpUriType型の仕様？のことを書いていたのだが、先日リリースされたOracle11g R1ではどうなったのか？

確かめてみた！　

まずは、SQL/XMLを利用した例。（以下は、Oracle11g R1 for Linux x86を利用。）

XML文書の文字エンコーディングはUTF-8、Oracleデータベースのキャラクタセットは、JA16SJISTILDE。

SCOTT> r
  1  select *
  2  from
  3    xmltable(
  4      'for $i in //*
  5       return $i'
  6      passing httpuritype('https://discus-hamburg.cocolog-nifty.com/test/atom.xml').getXML()
  7*   )
    passing httpuritype('https://discus-hamburg.cocolog-nifty.com/test/atom.xml').getXML()
                                                                                                *
行6でエラーが発生しました。:
ORA-31011: XML解析に失敗しました
ORA-19202: XML処理
LPX-00244: 小なり不等号 ('<')文字の使用が無効です。 (&lt;を使用します)
Error at line 30
中にエラーが発生しました
ORA-06512: "SYS.XMLTYPE", 行5
ORA-06512: "SYS.HTTPURITYPE", 行97


SCOTT>

あ〜〜〜〜やっぱり、ダメね〜。上記はXML文書のパースエラーとして現れているのだが、その原因は文字化けなのである。

XML文書とOracleデータベースのキャラクタセットが異なる場合（前述の例では、UTF-8とSJIS）にはHttpUriType型を利用せず、UTL_HTTPパッケージを利用し、

UTL_HTTP.SET_HEADER(v_req, 'Content-Type', 'text/xml;charset=UTF-8');

のようにすることで文字化けせずにXML文書を取込むことができる。
尚、XML文書、データベースキャラクタセットが同一である場合（XML文書がUTF-8でデータベースキャラクタセットがAL32UTF8のような場合）には文字化けは発生しない。これは私個人の想像なのだが、HttpUriType型が裏でHTTP通信する際に利用する文字エンコーディングはデータベースキャラクタセットから導出しているのだと思われる。今のところHttpUriType型には文字エンコーディングは指定できないのでオラクルさんが方針を変えない限り文字化けの回避策は前述の２つしかないだろう。

2007/11/28追記
もしどうしてもXML文書の文字エンコーディングとデータベースキャラクタセットが異なる環境でHTTPURITYPE型を使いたいということであれば、代替策としてUTL_HTTPパッケージを利用したユーザ定義型を作成すれば可能かもしれない。
（あくまで推測。。あとで試してみるか＝＞TODO）

以前、DBMS_XMLPARSER.PARSE(parser, uri)を使ってFEEDを直接参照した場合も同様のエラーだったが、UTL_HTTPパッケージを利用して文字化けを回避した。
以下URL参照のこと。（下記のエントリの内容はOracle10g R1/R2で試したものです。）
Mac De PL/SQL RSS Reader #3

SQL/XML機能が充実してきたので今後はあまり使わなくなるかもしれないが、次いでなのでDBMS_XMLPARSER.PARSER(parser,uri)でも試してみた。
DBMS_XMLPARSER.PARSER(parser, uri)でもHttpUriType型を利用しているだろうから結果は同じはずだ。
(また、XMLマスタープロフェッショナル（データベース）ネタからは離れてく〜〜。w）

以前作成したコードを少々手直してOracle11gで実行！（Oracle SQL Developer for MacOSXを利用した）

● ソース

CREATE OR REPLACE PROCEDURE GET_FEED(i_url IN VARCHAR2)
AS
  v_url             VARCHAR2(32767);
  v_myParser        DBMS_XMLPARSER.Parser;
  v_rssDoc          DBMS_XMLDOM.DomDocument;
  v_xml             XMLTYPE;

  PROCEDURE println(str IN VARCHAR2)
  IS
  BEGIN 
    DBMS_OUTPUT.PUT_LINE(str);
  END;

  PROCEDURE println
  (
    i_text IN CLOB
  )
  IS
    v_tempStr     VARCHAR(32767);
    v_numOfPieces PLS_INTEGER;
  BEGIN
    v_numOfPieces := CEIL(LENGTH(i_text)/1000);
    FOR i IN 1..v_numOfPieces LOOP
      DBMS_OUTPUT.PUT_LINE(SUBSTR(i_text, ((i-1)*1000), 1000));
    END LOOP;
  EXCEPTION
    WHEN OTHERS THEN
      DBMS_OUTPUT.PUT_LINE(
        'println(CLOB) internal procedure:'
        || sqlerrm()
      );
      RAISE;
  END println;

--****************************************************************************
--* Main 
--****************************************************************************
BEGIN
  DBMS_OUTPUT.ENABLE(200000);
  println('begin...');


  v_url := i_url;
  IF v_url IS NULL THEN
    RAISE_APPLICATION_ERROR(-20000, 'URLを指定してください。');
  END IF;

  v_myParser := DBMS_XMLPARSER.NEWPARSER();
  DBMS_XMLPARSER.PARSE(v_myParser, v_url);
  v_rssDoc := DBMS_XMLPARSER.GETDOCUMENT(v_myParser);
  v_xml := DBMS_XMLDOM.GETXMLTYPE(v_rssDoc);
  println('DBMS_XMLPARSERバージョン：'||DBMS_XMLPARSER.GETRELEASEVERSION());
  println('DBMS_XMLDOMバージョン   ：'||DBMS_XMLDOM.GETVERSION(v_rssDoc));
  println(' ');
  println('=== パース済みDOMから取得したRSSソース ===');
  println(XmlType.GETCLOBVAL(v_xml));
  println('====================');
  println(' ');
  DBMS_XMLPARSER.FREEPARSER(v_myParser);

  println('...End');

EXCEPTION
  WHEN OTHERS THEN
    DBMS_OUTPUT.PUT_LINE(
      'Main Procedure:'
      || sqlerrm()
    );
    RAISE;

END GET_FEED;

●　結果

RSS FEED(UTF-8)をデータベースキャラクタセット(JA16SJISTILDE)から取込んだ場合。

Connecting to the database Oracle11g R1 Scott(leaffish) - JA16SJISTILDE.
ORA-31011: XML解析に失敗しました
ORA-19202: XML処理
LPX-00244: 小なり不等号 ('<')文字の使用が無効です。 (&lt;を使用します)
Error at line 30
中にエラーが発生しました
ORA-06512: "SCOTT. GET_FEED", 行161
ORA-06512: 行6
begin...
Main Procedure:ORA-31011: XML解析に失敗しました
ORA-19202: XML処理
LPX-00244: 小なり不等号 ('<')文字の使用が無効です。 (&lt;を使用します)
Error at line 30
中にエラーが発生しました
Process exited.
Disconnecting from the database Oracle11g R1 Scott(leaffish) - JA16SJISTILDE.

RSS FEED(UTF-8)をデータベースキャラクタセット(AL32UTF8)から取込んだ場合。文字エンコーディングが同じ場合は問題なし！
ところで、Oracle11g R1でも、DBMS_XMLPARSERのパージョンは10.1.0.2.0なのね〜。(^^;;;

Connecting to the database Oracle11g R1 Scott(guppy) - AL32UTF8.
begin...
DBMS_XMLPARSERバージョン：10.1.0.2.0
DBMS_XMLDOMバージョン   ：1.0
 
=== パース済みDOMから取得したRSSソース ===
<?xml version="1.0" encoding="utf-8"?>

<feed xmlns="http://www.w3.org/2005/Atom">
    <title>Mac De Oracle</title>
    <link rel="alternate" type="text/html" href="https://discus-hamburg.cocolog-nifty.com/mac_de_oracle/" />
    <link rel="service.post" type="application/x.atom+xml" href="http://app.cocolog-nifty.com/t/atom/weblog/blog_id=121907" title="Mac De Oracle" />
    <id>tag:app.cocolog-nifty.com,2003:weblog-121907</id>
    <updated>2007-11-19T09:16:39Z</updated>


・・・・中略・・・・


        <summary>前回、何かが違うと感じたと書いたがそれはなにか？　実はwhitespaceに関す...</summary>
        <author>
            <name>discus</name>
        </author>
        <category term="Linux" />
        <category term="Oracle" />
        <category term="Oracle Database 11g" />
        <category term="XML" />




    </entry>

</feed>
====================
 
...End
Process exited.
Disconnecting from the database Oracle11g R1 Scott(guppy) - AL32UTF8.

尚、Oracle11g R1ではセキュリティが強化されている。（Oracle10g R2以前のセキュリティレベルにもできるようだが。。）上記のコードをそのまま実行しようとするとエラーになる。

ということで、セキュリティ関連も含めて続きは次回ということで。

---

おまけ

以下の資料はSQL/XMLって何？　ってとこからスタートする方にはよいかも..。
オープンソースカンファレンス２００７　.DBの資料「XQuery、XPath 及び SQL / XML に関する標準化動向と今後の取組み状況」 (PDF)

以下のサイトにはSQL/XML関連の情報がいろいろ（英語です。）
SQLX.org

その他、OTN-Jなどにもあったかも。。。（未確認）