PL/SQL de Conditional Compile #5 Tweet

さて、PL/SQL条件付きコンパイルもネタが無くなってきたので、最後に、DBMS_DB_VERSIONパッケージを利用して、各リリース毎にコードを切り替えてみよう！
ということで、Oracle database 10g以前のリリースとOracle databse 11g以降のリリースでコードを切り替える例。

●　条件付きコンパイルが無い場合、Oracle11gより前のリリースで以下ようなコードを書いてしまったら....

当然コンパイルエラー！

FUNCTION CONDITIONAL_COMP_SAMPLE3 RETURN NUMBER
IS
  vSeq# NUMBER;
BEGIN
  vSeq# := mySeq.NEXTVAL;
  RETURN vSeq#;
END CONDITIONAL_COMP_SAMPLE3;
/

警告: ファンクションが変更されましたが、コンパイル・エラーがあります。

SCOTT> show errors
FUNCTION CONDITIONAL_COMP_SAMPLE3のエラーです。

LINE/COL ERROR
-------- -----------------------------------------------------------------
9/5      PL/SQL: Statement ignored
9/20     PLS-00357:
         表またはビュー、シーケンス参照MYSEQ.NEXTVALは、このコンテキストで
         は使用できません。

SCOTT> 

●　しかし、DBMS_DB_VERSIONパッケージでリリース毎にコードを選択し切り替えたら・・・・便利ですよね。

CREATE OR REPLACE FUNCTION CONDITIONAL_COMP_SAMPLE3 RETURN NUMBER 
IS
  vSeq# NUMBER;
BEGIN

  $IF DBMS_DB_VERSION.Ver_LE_10 $THEN
    SELECT mySeq.NEXTVAL INTO vSeq# FROM DUAL;
  $ELSE
    vSeq# := mySeq.NEXTVAL;
  $END
  
  RETURN vSeq#;
  
END CONDITIONAL_COMP_SAMPLE3;

DBMS_DB_VERSIONパッケージをリリース番号でどのようにソースコードが変化するか確認。
●　Oracle database 10g以前のバージョンでコンパイルした場合

SCOTT> 
SCOTT> set serveroutput on
SCOTT> exec dbms_preprocessor.print_post_processed_source('FUNCTION','SCOTT','CONDITIONAL_COMP_SAMPLE3');
FUNCTION CONDITIONAL_COMP_SAMPLE3 RETURN NUMBER
IS
vSeq# NUMBER;
BEGIN
SELECT mySeq.NEXTVAL INTO vSeq# FROM DUAL;
RETURN vSeq#;
END CONDITIONAL_COMP_SAMPLE3;

PL/SQLプロシージャが正常に完了しました。

●　Oracle database 11g以降でコンパイルした場合

SCOTT> exec dbms_preprocessor.print_post_processed_source('FUNCTION','SCOTT','CONDITIONAL_COMP_SAMPLE3');
FUNCTION CONDITIONAL_COMP_SAMPLE3 RETURN NUMBER
IS
vSeq# NUMBER;
BEGIN
vSeq# := mySeq.NEXTVAL;
RETURN vSeq#;
END CONDITIONAL_COMP_SAMPLE3;

PL/SQLプロシージャが正常に完了しました。

SCOTT> 

●　各リリース毎のDBMS_DB_VERSIONパッケージの違い
参考　http://download.oracle.com/docs/cd/B19306_01/appdev.102/b14258/d_dbver.htm

● 10.2:

package DBMS_DB_Version is 
  Version       constant pls_integer := 10; 
  Release       constant pls_integer := 2; 
  Ver_LE_9_1    constant boolean := false; 
  Ver_LE_9_2    constant boolean := false; 
  Ver_LE_9      constant boolean := false; 
  Ver_LE_10_1   constant boolean := false; 
  Ver_LE_10_2   constant boolean := true; 
  Ver_LE_10     constant boolean := true; 
end DBMS_DB_Version; 

● 10.1:

package DBMS_DB_Version is 
  Version       constant pls_integer := 10; 
  Release       constant pls_integer := 1; 
  Ver_LE_9_1    constant boolean := false; 
  Ver_LE_9_2    constant boolean := false; 
  Ver_LE_9      constant boolean := false; 
  Ver_LE_10_1   constant boolean := true; 
  Ver_LE_10     constant boolean := true; 
end DBMS_DB_Version; 

● 9.2:

package DBMS_DB_Version is 
  version       constant pls_integer := 9; 
  release       constant pls_integer := 2; 
  Ver_LE_9_1    constant boolean := false; 
  Ver_LE_9_2    constant boolean := true; 
  Ver_LE_9      constant boolean := true; 
end DBMS_DB_Version;

---

・PL/SQL de Conditional Compile #1
・PL/SQL de Conditional Compile #2
・PL/SQL de Conditional Compile #3
・PL/SQL de Conditional Compile #4