PL/SQL de File Upload / Download #4 Tweet

---

Howard Jones - The Peaceful Tour - Things Can Only Get Better

---

PL/SQL de File Upload / Download　のつづきです。

前回は、MacOSXのSafariで発生する問題。日本語ファイル名のファイルをダウンロードした際、ファイル名が、 hostname.拡張子　のような形式で保存されてしまうというところまでだった。
Firefoxでは全く問題が発生していないので、ブラウザ依存の問題ということなのだろうか。

ということで、今回は、MacOSX以外のプラットフォームで試した結果＋αも。

---

OTN-J の　Code Tipsでも公開されました。(2007/6/16更新）
http://otn.oracle.co.jp/otn_pl/otn_tool/code_detail?n_code_id=2235
http://otn.oracle.co.jp/otn_pl/otn_tool/code_detail?n_code_id=2236

---

ファイル名が日本語であるファイルをダウンロードした場合のファイル名の文字化けについて

・Firefox 2 (Mozilla含む） : MacOSX/Linux/Windows XP　すべてのプラットフォームで
　文字化け等の問題は発生しない。

　　

・IE6 : 文字化け。

・Safari : 前述の通り。　hostname.拡張子　という形式で保存されてしまう。

・Opera 9.2 (MacOSX版）: URLエンコードされた文字列.拡張子 という形式で保存されてしまう

文字エンコードが統べてUTF-8だったらどうなんだろう。。。解決できたりして。。。という思いつきは置いといて、今日は、Shift_JISのままでIE6での文字化けを（無理矢理？）解決する方法があったので載せておくことにする。

参考：
http://otndnld.oracle.co.jp/document/products/oracle10g/102/doc_cd/server.102/B19260-01/concept.htm#i1011220

※2007/6/8一部修正
以下のようにContent-Disposition: attachment; filename=UTF-8でURLエンコードしたファイル名を指定する方式であれば、IE6でも正しいファイル名で保存できるようになる。
MacOSXのSafariでは依然として改善されず、下記方法では文字化けしてしまう。　

以下の方法もマニュアルに記載されている方法だが、あくまで英語圏で作成されたマニュアルの翻訳なので、ファイル名が日本語である場合の文字化け回避方法までは記載されていない。
文字化けの回避はブラウザにも依存する部分なのでなかなか面倒ですね。文字コードやエンコーディングがいろいろとありすぎてうれしくないな〜。

create or replace PROCEDURE fileDownloader
IS
  vFilePath     VARCHAR2(256);
  vUserAgent    VARCHAR2(512);
  vContentType  discusdoctable.BLOB_CONTENT%TYPE;
  vMimeType     discusdoctable.MIME_TYPE%TYPE;
  vDocSize      discusdoctable.DOC_SIZE%TYPE;
  vFileName     discusdoctable.NAME%TYPE;

BEGIN
  vFilePath := SUBSTR(owa_util.get_cgi_env('PATH_INFO'), 2);
  vUserAgent := owa_util.get_cgi_env('HTTP_USER_AGENT');
  IF INSTR(vUserAgent,'MSIE') != 0 THEN
    -- IE　(かなり無理矢理な対応）
    -- IE6 - Version 6.0.290000.2180.xpsp_sp2_dgr.070227-2254 で動作確認！
    -- 他のバージョンのIEではどうなるか未確認。。。
    SELECT
      SUBSTR(name, INSTR(name, '/')+1),
      blob_content,
      mime_type,
      doc_size
    INTO
      vFileName,
      vContentType,
      vMimeType,
      vDocSize
    FROM
      discusDocTable
    WHERE
      name = vFilePath;
    OWA_UTIL.mime_header(vMimeType, FALSE);
    HTP.p('Content-Length: ' || TO_CHAR(vDocSize));
    HTP.p(
        'Content-Disposition: attachment; filename=' || utl_url.escape(vFileName,false, 'AL32UTF8')
      );
    OWA_UTIL.http_header_close;
    wpg_docload.download_file(vContentType);
  ELSE
    -- その他のブラウザ（MacOSX Safariでは日本語ファイル名のダウンロードは文字化けする）
    wpg_docload.download_file(vFilePath);
  END IF;
EXCEPTION
  WHEN OTHERS THEN
    htp.htmlopen;
    htp.headopen;
    htp.meta('Ccntent-Type',null,'text/html; charset=Shift_JIS');
    htp.headclose;
    htp.bodyopen;
    htp.print('ダウンロードファイル:' || vFilePath);
    htp.print('<strong style="color:#ff0000">' || sqlerrm() || '</strong>');
    htp.bodyclose;
    htp.htmlclose;
END fileDownloader;
/

IE6で日本語ファイル名のファイルをダウンロードしたスクリーンショット。