Mac De PL/SQL RSS Reader #5 Tweet

前回のつづきです。
当初のからmegawattさんのRSS 0.91フォーマットを対象にしているためその他のRSSフォーマットやATOMには対応していない。元ネタのようにXSLTスタイルシートを利用するのも良いだろう。
今回は、「元ネタの通りの方法で、日本語が文字化け無く処理できるのだろうか？」　という点を確認するということが目的であるため複数のRSSフォーマットに対応するつもりは無い。そのウチ試す予定だが。

ということで、最後に、今までほったらかしていた　Oracle HTMLDB 2.0　を利用して　RSS Reader　を組み込んでみることにした。
Oracle HTMLDB 2.0については以前の記事を参考にして貰いたい。



HTMLDBに組み込んだコードはこれ。

DECLARE
  TYPE rss_type IS RECORD
  (
    title       VARCHAR2(2000),
    link        VARCHAR2(200)
  );
  v_rss_item        rss_type;
  v_rss_empty_item  rss_type;

  v_url             VARCHAR2(32767) 
    := 'http://megawatt.blogdns.net/blog/rdf91_xml';

  v_myParser        DBMS_XMLPARSER.Parser;
  v_rssDoc          DBMS_XMLDOM.DomDocument;
  v_itemNode        DBMS_XMLDOM.DomNode;
  v_childnode       DBMS_XMLDOM.DomNode;
  v_rssEntryList    DBMS_XMLDOM.DomNodeList;
  v_rssItemFields   DBMS_XMLDOM.DomNodeList;
  v_childNodeText   VARCHAR2(32767);

  v_req             UTL_HTTP.REQ;
  v_resp            UTL_HTTP.RESP;

  v_source          VARCHAR2(1024);
  v_tempSourceClob  CLOB;
  v_tempXMLTYPE     XMLTYPE;


  PROCEDURE report_rss_item(p_rss_item IN rss_type)
  IS
  BEGIN
    HTP.TABLEROWOPEN();
    HTP.TABLEDATA( 
      '<a href="' 
      || p_rss_item.link
      || '" style="color:#FF0000" target="_blank">' 
      || p_rss_item.title 
      || '</a>'
    );
    HTP.TABLEROWCLOSE();

  EXCEPTION
    WHEN OTHERS THEN
      HTP.PRINT('Error occured in report_rss_item internal procedure');
      RAISE;
  END report_rss_item;
  
--****************************************************************************
-- Main procedure
--****************************************************************************
BEGIN
  v_req := UTL_HTTP.BEGIN_REQUEST(v_url);
  UTL_HTTP.SET_HEADER(v_req, 'User-Agent', 'Oracle UTL_HTTP/Oracle10g R1');
  UTL_HTTP.SET_HEADER(v_req, 'Content-Type', 'text/xml;charset=UTF-8');
  v_resp := UTL_HTTP.GET_RESPONSE(v_req);

  DBMS_LOB.CREATETEMPORARY(v_tempSourceClob, FALSE);
  BEGIN
    LOOP
      UTL_HTTP.READ_LINE(v_resp, v_source, true);

      -- 改行コード強制的に付加。
      -- xml_println()でDBMS_OUTPUT.PUT_LINE()が、最大２５５文字までしか
      -- 表示できないことへの一時的な対策。(試しているサイトについてはこれで
      -- 回避できているので今のところはこのままで。）
      v_source := v_source || UTL_TCP.CRLF;
      DBMS_LOB.WRITEAPPEND(v_tempSourceClob, LENGTH(v_source), v_source);


    END LOOP;
  EXCEPTION
    WHEN UTL_HTTP.END_OF_BODY THEN
      UTL_HTTP.END_RESPONSE(v_resp);
  END;

  v_myParser      := DBMS_XMLPARSER.NEWPARSER();
  DBMS_XMLPARSER.PARSECLOB(v_myParser, v_tempSourceClob);
  v_rssDoc        := DBMS_XMLPARSER.GETDOCUMENT(v_myParser);
  v_tempXMLType   := DBMS_XMLDOM.GETXMLTYPE(v_rssDoc);
  v_rssEntryList  := DBMS_XMLDOM.GETELEMENTSBYTAGNAME(v_rssDoc, 'item');
  v_rss_item      := v_rss_empty_item;

  HTP.TABLEOPEN();
  HTP.TABLEROWOPEN();
  HTP.TABLEHEADER(
    cvalue => v_tempXMLType.EXTRACT('/rss/channel/title/text()').GETSTRINGVAL
              || ' - most recent '
              || DBMS_XMLDOM.GETLENGTH(v_rssEntryList)
              || ' articles:',
    cattributes => 'style="font-size:18px"',
    calign => 'align="left"'
  );
  HTP.TABLEROWCLOSE();

  FOR i IN 1..DBMS_XMLDOM.GETLENGTH(v_rssEntryList) LOOP
    v_itemNode      := DBMS_XMLDOM.ITEM(v_rssEntryList, i-1);
    v_rssItemFields := DBMS_XMLDOM.GETCHILDNODES(v_itemNode);

    FOR j IN 1..DBMS_XMLDOM.GETLENGTH(v_rssItemFields) LOOP
      v_childnode     :=  DBMS_XMLDOM.ITEM(v_rssItemFields, j-1);
      v_childNodeText :=  DBMS_XMLDOM.GETNODEVALUE(
                            DBMS_XMLDOM.GETFIRSTCHILD(v_childnode)
                          );

      CASE DBMS_XMLDOM.GETNODENAME(v_childnode)
        WHEN 'title' THEN
          v_rss_item.title := v_childNodeText;

        WHEN 'link' THEN
          v_rss_item.link := v_childNodeText;

        ELSE
          NULL;
      END CASE;
    END LOOP;
    report_rss_item(v_rss_item);
  END LOOP;

  HTP.TABLECLOSE();
  DBMS_LOB.FREETEMPORARY(v_tempSourceClob);
  DBMS_XMLPARSER.FREEPARSER(v_myParser);

EXCEPTION
  WHEN OTHERS THEN
    HTP.PRINT(
      'Main Procedure:'
      || sqlerrm()
    );
    RAISE;
END;

前回のストアドプロシージャのロジックとの違いはあまり無いが、無名PL/SQLブロックとして組み込むことと、DBMS_OUTPUTパッケージを利用している部分を、HTPパッケージを利用するように変更しなければならない。（やっつけ仕事的なコードになってしまったなが、文字化け回避の方法が見えればOKなので他には目をつぶってくださいませ。。。）

尚、
HTPパッケージについては、PL/SQL パッケージ・プロシージャおよびタイプ・リファレンス
HTMLDB 2.0についてはOracle HTMLDB 2.0（英語）や、HTMLDB 2.0のオンラインヘルプなどが参考になるだろう。
＃今回は、オンラインヘルプしか利用ませんでした。そんな程度でも作れるくらい簡単です。。。

次回は、HTMLDB 2.0 に前述の無名PL/SQLブロックを組み込んで試すことにする。




これから見ようとしているDVD：
随分前、こんな記事を書いたが、なんと ザ・インターネット２がリリースされていた。
邦題：インターネットの続編？のようなのだが。。。。不覚にも全くしらなかった。でも主演はサンドラブロックではなさそうだな。。。そういえば、ザ・インターネットが公開されたのは１９９６年。１０年も経ったのか・・・と。


ところで、インターネット２っていうと、次世代インターネットを指していたりする。

##############################
2006/08/13
ザ・インターネット２見ましたが、ぜんぜん面白くない。ザ・インターネットの続編だなんて、とんでもない無いですね。
ザ・インターネットの延長線上にあると思ってみてしまうとがっかりするので、完全に別ものと思って見てくださいね。