Mac De Oracle (PL/SQL De COMPRESS) Tweet

解凍につづき、圧縮を試す。

まずは gzip するテキストファイルは前回準備しておいたものを利用する。このテキストファイルをcompressed_file.gzとして圧縮してみる。尚、UTL_COMPRESS.LZ_COMPRESS()では、圧縮レベルが１〜９あり、デフォルトは、６。最も圧縮率が高いのは、９。この例では、圧縮率＝６（デフォルト）で圧縮する。

G5Server:˜ oracle$ ls -l
total 48096
中略
-rw-r--r--     1 oracle    oinstall       559 Aug 20 06:35 org.txt
中略
G5Server:˜ oracle$ 
G5Server:˜ oracle$ cat org.txt
操作上の注意 
■ LZ* ファンクションによって戻された一時 LOB は、コール元が 
   DBMS_ LOB.FREETEMPORARY コールを使用して解放する必要があります。 
■ LZ_COMPRESS* または LZ_UNCOMPRESS* に渡された BFILE は、
   DBMS_LOB.FILEOPENでオープンする必要があります。 
■ 特別な状況(入力がすでに圧縮されている場合)では、UTL_COMPRESS サブプログラムの
   1 つで生成された出力が、入力と同じ大きさかまたは入力よりもわずかに大きくなる
   ことがあります。 
■ UTL_COMPRESS で圧縮したデータの出力は、1 つのファイル上の gzip(-n オプション を指定)/gunzip と
   互換性があります。
G5Server:˜ oracle$

早速取りかかる。今回も　Oracle SQL Developer 1.0 for MacOSXを利用する。

だ〜〜〜〜っと、前回のコードを少々修正して実行（無名PL／SQLブロックにしてあるが、ストアドプロシージャでもファンクションでも、パッケージで実装しても全く問題はない。尚、事前にディレクトリオブジェクトは作成してある。）

圧縮ファイル(compressed_file.gz）が正しく作成できたか確認する。

G5Server:˜ oracle$ ls -l
total 48112
中略
-rw-r--r--     1 oracle    oinstall       408 Aug 20 13:11 compressed_file.gz
-rw-r--r--     1 oracle    oinstall       559 Aug 20 06:35 org.txt
中略
G5Server:˜ oracle$ 
G5Server:˜ oracle$ gunzip -lt compressed_file.gz
         compressed        uncompressed  ratio uncompressed_name
                408                 559  30.2% compressed_file
G5Server:˜ oracle$
G5Server:˜ oracle$ gunzip -c compressed_file.gz
操作上の注意 
■ LZ* ファンクションによって戻された一時 LOB は、コール元が 
   DBMS_ LOB.FREETEMPORARY コールを使用して解放する必要があります。 
■ LZ_COMPRESS* または LZ_UNCOMPRESS* に渡された BFILE は、
   DBMS_LOB.FILEOPENでオープンする必要があります。 
■ 特別な状況(入力がすでに圧縮されている場合)では、UTL_COMPRESS サブプログラムの
   1 つで生成された出力が、入力と同じ大きさかまたは入力よりもわずかに大きくなる
   ことがあります。 
■ UTL_COMPRESS で圧縮したデータの出力は、1 つのファイル上の gzip(-n オプション を指定)/gunzip と
   互換性があります。
G5Server:˜ oracle$

前述のように、gunzipで解凍してしまうのもよいのだが、ダブルクリックして解凍しちゃいましょう。すばらしいGUIがあるんですから。

以下に今回作成したコードを示す。

DECLARE
  v_src_text_file         BFILE;
  v_compressed_blob       BLOB;
  v_directory_name        VARCHAR2(30);
  v_src_text_file_name    VARCHAR2(510);
  v_dest_file_name        VARCHAR2(510); 

  PROCEDURE close_bfile
  (
    i_bfile IN OUT NOCOPY BFILE
  ) 
  IS
  BEGIN
    IF DBMS_LOB.ISOPEN(i_bfile) = 1 THEN
      DBMS_LOB.CLOSE(i_bfile);
    END IF;
  END close_bfile;

  PROCEDURE write_blob_to_file
  (
    i_directory_name  IN VARCHAR2,
    i_file_name       IN VARCHAR2,
    i_src_blob        IN OUT NOCOPY BLOB
  ) 
  IS
    v_file UTL_FILE.FILE_TYPE;
  BEGIN
    v_file := UTL_FILE.FOPEN(
                UPPER(i_directory_name), 
                i_file_name, 
                'wb', 
                32767
              );

    -- ファイルへ書き出すBLOBはオープンされていることを前提とする
    DECLARE
      c_chunk_size   CONSTANT PLS_INTEGER := 32767;

      v_buffer RAW(32767);
      v_amount PLS_INTEGER := c_chunk_size;      
      v_num_of_chunk PLS_INTEGER;
    BEGIN
      v_num_of_chunk := CEIL(DBMS_LOB.GETLENGTH(i_src_blob)/c_chunk_size);
      FOR chunk# IN 1..v_num_of_chunk LOOP
        DBMS_LOB.READ(
          i_src_blob, 
          v_amount, 
          (c_chunk_size * (chunk# - 1)) + 1, /*offset*/
          v_buffer
        );
        UTL_FILE.PUT_RAW(v_file, v_buffer, TRUE);
      END LOOP;
    END;

    UTL_FILE.FCLOSE(v_file);
  END write_blob_to_file;
--
BEGIN
  -- ディレクトリ名の設定
  v_directory_name     := 'MYDIR';
  -- テキストファイル名
  v_src_text_file_name := 'org.txt';
  -- 出力ファイル名
  v_dest_file_name     := 'compressed_file.gz';
  
  DBMS_OUTPUT.PUT_LINE('========== compress start ==========');
  
  -- テキストファイルをBFILEとして開く。
  v_src_text_file 
    := BFILENAME(UPPER(v_directory_name), v_src_text_file_name);
  DBMS_LOB.OPEN(v_src_text_file);
        
  -- BFILEを圧縮し、一時BLOBへ (圧縮品質はデフォルトで圧縮する）
  v_compressed_blob := UTL_COMPRESS.LZ_COMPRESS(v_src_text_file);
  
  -- BLOB（圧縮済み）を書き出す
  write_blob_to_file(
    UPPER(v_directory_name), 
    v_dest_file_name, 
    v_compressed_blob
  );
    
  -- 一時LOBの解放及び、BFILEのクローズ
  DBMS_LOB.FREETEMPORARY(v_compressed_blob);
  close_bfile(v_src_text_file);

  DBMS_OUTPUT.PUT_LINE('========== compress end   ==========');

EXCEPTION
  WHEN OTHERS THEN
    -- 一時LOBの解放及び、BFILEのクローズ
    DBMS_LOB.FREETEMPORARY(v_compressed_blob);
    close_bfile(v_src_text_file);
    RAISE;
END;
/

OTN JapanのCodeTipsに公開してあります。
聞いている曲：
KraftWerk - Minimum - Maximum (live)